#!/usr/bin/perl -w
#
# ecaccess-file-chmod: Change ECaccess File Mode Bits
#
# Laurent.Gougeon@ecmwf.int - 2010-10-15

use ECMWF::ECaccess;
use Getopt::Long;
use Pod::Usage;

my %opt = ( version => 0, help => 0, manual => 0, retry => 0, debug => 0 );

pod2usage( -noperldoc => 1, -exit => 1, verbose => 1 ) if !GetOptions(
	\%opt,
	qw(
	  version
	  help|?
	  manual
	  retry=i
	  debug
	  )
);

# Display version if requested
die ECMWF::ECaccess->VERSION . "\n" if ( $opt{version} );

my $mode         = $ARGV[0];
my $ecaccessFile = $ARGV[1];

pod2usage( -noperldoc => 1, -exit => 1, verbose => 1 ) if ( $opt{help} );
pod2usage( -noperldoc => 1, -exit => 1, verbose => 2 ) if ( $opt{manual} );
pod2usage( -noperldoc => 1, -exit => 1, verbose => 0, -msg => "No mode specified!\n" )          if not($mode);
pod2usage( -noperldoc => 1, -exit => 1, verbose => 0, -msg => "No ecaccess-file specified!\n" ) if not($ecaccessFile);

# Create the ECaccess Controler
my $ecaccess = ECMWF::ECaccess->new( $opt{retry}, $opt{debug});

# Get the Token (using the Certificate in $HOME)
my $token = $ecaccess->getToken();

# Get the Control Channel
my $controlChannel = $ecaccess->getControlChannel();

# Trigger the event
$controlChannel->changeFileMode( $token, $mode, $ecaccessFile );

# Logout
END {
  $ecaccess->releaseToken($token) if ($token);
}

__END__

=head1 NAME

ecaccess-file-chmod - Change ECaccess File Mode Bits

=head1 SYNOPSIS

B<ecaccess-file-chmod -version|-help|-manual>

B<ecaccess-file-chmod [-debug]> I<mode> I<ecaccess-file>

=head1 DESCRIPTION

Allow changing the ECaccess File Mode Bits of the given I<ecaccess-file> according to I<mode>, which is an octal number
representing the bit pattern for the new mode bits.

The I<ecaccess-file> is in the form [domain:][/user-id/]path. Please read the "Shell commands -> File Management" section of
the "ecaccess" guide for more information on the ECaccess File System.

=head1 ARGUMENTS

=over 8

=item I<mode>

Octal number representing the bit pattern for the new mode bits (e.g. 0600).

=item I<ecaccess-file>

The name of the ECaccess File to change the File Mode Bits.

=back

=head1 OPTIONS

=over 8

=item B<-version>

Display version number and exits.

=item B<-help>

Print a brief help message and exits.

=item B<-manual>

Prints the manual page and exits.

=item B<-retry> I<count>

Number of SSL connection retries per 5s to ECMWF. This parameter only apply to the
initial SSL connection initiated by the command to the ECMWF server. It does not
apply to all the subsequent requests made afteward as it is mainly targeting errors
that can happen from time to time during the SSL handshake. Default is no retry.

=item B<-debug>

Display the SOAP and SSL messages exchanged.

=back

=head1 EXAMPLES

B<ecaccess-file-chmod> I<0700> I<ec:bin/a.out>

Change the File Mode Bits to Read and Write for owner and Read for everybody else on a File in the bin directory of the ECFS
directory of the authenticated user.

=head1 SEE ALSO

B<ecaccess-file-delete>, B<ecaccess-file-get>, B<ecaccess-file-mget>, B<ecaccess-file-modtime>, B<ecaccess-file-mput>,
B<ecaccess-file-rmdir>, B<ecaccess-file-copy>, B<ecaccess-file-dir>, B<ecaccess-file-mdelete>, B<ecaccess-file-mkdir>,
B<ecaccess-file-move>, B<ecaccess-file-put>, B<ecaccess-file-size> and B<ecaccess>.

=cut
